You are currently viewing Thêm RSS feed vào email trong MC

Thêm RSS feed vào email trong MC

Cập nhật nội dung là một điều đau đầu mà nhiều người làm SEO, marketer đối mặt. Vậy làm sao có thể giúp khách hàng dễ dàng tìm thấy những thông tin mới nhất của bạn? Cho dù bạn xuất bản nội dung mới đều đặn hay đột nhiên cảm hứng chợt tới thì hãy đảm bảo rằng nhóm đọc giả mà bạn nhắm tới sẽ không bỏ lỡ các thông tin quan trọng!

Tạo nội dung cho bài viết là một công việc tốn nhiều thời gian và chất xám rồi, vì thế không nên mất nhiều thời gian trong việc đưa đến những thông tin mà bạn đã bỏ công sức khó nhọc tạo ra. Ở bài này Gâu Đần sẽ đưa RSS feed vào trong email giúp người đọc duy trì và cập nhật thường xuyên với những thông tin mới nhất trên trang web của bạn nhé.

Tình huống

Báo VN tàu nhanh muốn sử dụng Marketing Cloud để gửi email cảm ơn và xác nhận đến những khách hàng vừa renew subscription ở trang báo này, đồng thời họ cũng muốn hiển thị một số bài viết của họ thông qua RSS feed của website. Email gửi đọc giả phải dynamic và kèm đó là cập nhật giới thiệu các bài viết mới nhất kể từ lúc gửi!

RSS feed

RSS feed là một tập tin XML, giúp tạo ra kênh tóm tắt thông tin. Nguyên tắc của file này là tối giản và theo một pattern có quy luật. Ở đây VN tàu nhanh có cung cấp các RSS ở ĐÂY. Ở ví dụ này thì Đần chọn “RSS trang chủ” nhé.

Note: dĩ nhiên bạn có thể chọn các RSS khác hoặc nguồn khác, tùy bạn

Ở đây để đơn giản: ta đặt ra mục tiêu sẽ lấy được tiêu đề và link

Vào xem thì nhận thấy: tiêu đề và link nằm ở node “title” và “link” phía sau node “channel” và “item”

Sau khi xác định được vị trí của các node thì ta tiến hành coding.

Dùng AMPscript để kéo thông tin

Vì đây là tập tin dạng XML nên phù hợp nhất là sử dụng BuildRowsetFromXML function

%%[
var @xml, @title, @link, @rowCount
set @rss = 'https://vnexpress.net/rss/tin-moi-nhat.rss'
set @xml = HTTPGet(@rss)
set @title = BuildRowSetFromXML(@xml, '//item/title', 1)
set @link = BuildRowSetFromXML(@xml, '//item/link', 1)
set @rowCount = RowCount(@link)
]%%
%%=v(@RowCount)=%%

XPATH string dùng trong function này có thể diễn giải là bỏ qua node đầu tiên (channel), lấy thông tin ở node có dạng item/title

Ta nhận thấy sau khi pull và tạo ra set từ XML có khá nhiều record, đưa vào hết trong email có lẽ không ổn lắm nên ở đây Đần sẽ giới hạn là 5. Nếu RSS feed nhiều hơn 5 thì chỉ lấy 5 bài báo mới nhất.

%%[
var @xml, @titleNode, @linkNode, @rowCount, @rows
set @rss = 'https://vnexpress.net/rss/tin-moi-nhat.rss'
set @xml = HTTPGet(@rss)
set @titleNode = BuildRowSetFromXML(@xml, '//item/title', 1)
set @linkNode = BuildRowSetFromXML(@xml, '//item/link', 1)
set @rowCount = RowCount(@titleNode)
if @rowCount >= 5 then
    set @rows = 5
else set @rows = @rowCount
endif
if @rows > 1 then
    var @title, @link
    for @i = 1 to @rows do
        set @title = Field(Row(@titleNode, @i), 'Value')
        set @link = Field(Row(@linkNode, @i), 'Value')
        Output(Concat(@title, '<br>'))
        Output(Concat(@link, '<br><br>'))
    next @i
endif
]%%

Tới đây Gâu Đần thử “in”  title và link ra

Hmm trông có vẻ khá ổn áp. Nhìn thì tiêu đề và URL có match với nhau rồi đó. Chứng tỏ ta đã lấy đúng được thứ mình cần. Việc còn lại là thêm chút HTML để bỏ vào email

Full code

%%[
var @xml, @titleNode, @linkNode, @rowCount, @rows
set @rss = 'https://vnexpress.net/rss/tin-moi-nhat.rss'
set @xml = HTTPGet(@rss)
set @titleNode = BuildRowSetFromXML(@xml, '//item/title', 1)
set @linkNode = BuildRowSetFromXML(@xml, '//item/link', 1)
set @rowCount = RowCount(@titleNode)
if @rowCount >= 5 then
    set @rows = 5
else set @rows = @rowCount
endif
if @rows > 1 then
    var @title, @link
    for @i = 1 to @rows do
        set @title = Field(Row(@titleNode, @i), 'Value')
        set @link = Field(Row(@linkNode, @i), 'Value')
]%%
<div style="border: 1px solid #444; background-color: #F7F7F7; margin: 0.76em 0; padding: 0.76em;">
<h1 style="font: bold normal 1.0em Arial, Helvetica, sans-serif;"><a href="%%=RedirectTo(@link)=%%">%%=v(@title)=%%</a></h1>
</div>
%%[
    next @i
endif
]%%

Output

Đến đây bạn sẽ nghĩ lời lẽ trong email nghe cũng thống thiết đấy nhưng sao news feed trông đơn điệu vậy. Vậy thì cái này phụ thuộc vào tệp XML RSS feed họ cung cấp cho bạn có gì và bạn màu mè ra sao nữa. Như đây là cái mình custom theo ý của mình chẳng hạn

Bài này không nhận quảng cáo từ VN tàu nhanh, nhưng không có tiền thì làm MC làm sao? face with tears of joy

Leave a Reply